Day 193 - Friday Fail, angel hair edition

It's Friday! Also, this:

I was trying to make a smaller version of owens' Sierpinski tetrahedron model from Day 189, but stupidity got in the way. Specifically, I started the print and walked away before checking to make sure everything was okay. I know that I definitely Should Not Do This, but I did it anyway. Even worse, I also did it earlier in the day in the JMU MakerLab and caused a similar angel hair catastrophe that in that case required some serious cleanup and a replacement of the ceramic tape on the Replicator 2. In short, I was an idiot today, and the universe caught me on it twice. Fool me once...

Lessons learned which I either already knew or should have known but did not heed:

1. Models don't stick as well on tape as they do on acrylic. (See picture above.)
2. Models don't stick as well on glass as they do on glass with tape. (At the JMU MakerLab we have a new glass build platform!)

Day 192 - Mesh-testing a Gyroelongated Pentagonal Bicupola

Inspired by the many sets of polyhedral models on Thingiverse (for example pmoews' Archimedean Solids, Johnson Polyhedra, and Catalan Solids, and pdragy's Customizable Convex Polyhedra), today we experimented with ways to make wire-frame polyhedra. Our test subject was the gryoelongated pentagonal bicupola, which has regular polygon faces but non-regular behavior at its vertices. This sounds fancy but just means that the vertices can look different; for example, in this model there are some vertices that are surrounded by one pentagon, two squares, and one triangle, where in other places there are vertices that are surrounded by four triangles and a square.

Thingiverse link: http://www.thingiverse.com/thing:267193

Settings: MakerWare with custom settings from Day 110 on a Replicator 2.

Expensiveware warning: On this blog I try to stick to free and commonly available software, but for today's object I am pulling out the big guns and using Mathematica, which is very much not free. Mathematica's freeware baby cousin wolframalpha.com also knows about the gryo-pen-bic-whatsit, but Mathematica has much more data and power, and most importantly, can export models to STL.

Technical notes: It is easy to get a 3D polyhedral model in Mathematica using the built-in PolyhedronData package; for today's polyhedron it's as simple as:

PolyhedronData["GyroelongatedPentagonalBicupola"]

Mathematica can also output a wireframe, give specific vertex coordinates, calculate the surface area of the polyhedron, and lots of other things, including export to STL. However, Mathematica only reliably exports full models, not wireframes (as far as I can figure). We could use Mathematica's vertex coordinates to explicitly construct a wireframe model in OpenSCAD by combining the methods in Day 174 and Day 188, but that would require keeping track of vertex adjacency information. That might be tolerable for just one polyhedron, but would be way too tedious for constructing a big collection of different polyhedral wireframes.

So the problem is this: How to turn a model exported from Mathematica into a wireframe? This afternoon I was thinking about this problem and suddenly remembered that there is a little button in TopMod that looks like this:

Problem solved! Export the polyhedron from Mathematica to STL, convert to OBJ using MeshLab (or your favorite online converter) so we can open the file in TopMod, remove the edges and vertices from the mesh that we don't want included in the wireframe, and then press the magic button. The model pictured on the right is the result of this process. The one pictured in the back had a mesh refinement and then a Doo Sabin remesh (see Day 135), and the one pictured on the left had no refinement but then two Doo Sabin remeshings.

UPDATE: Bill Owens (owens on Thingiverse) points out that you can get Mathematica for free on a Raspberry Pi, so for some of you Mathematica *is* freeware!

Day 191 - Filament bracelet

Today we made something very simple: a small, thin rounded tube for turning a scrap of filament into a simple bracelet. Despite how simple this is, it took over a dozen prints to get it just right so that it would hold the filament securely. The resulting bracelet is the top one in the following picture:

Tinkercad link: https://tinkercad.com/things/1u7wu02ELWJ-day-191-filament-bracelet-clasp
Thingiverse link: http://www.thingiverse.com/thing:264544

Settings: MakerWare .1mm/high with raft but no support, in about 7 minutes on a Replicator 2.

Day 190 - One hundred triangle-squares

In bulk printing mode again. Over the past few days we have printed 100 of the Hinged Triangle-Square models from Day 189, for a giveaway at an upcoming conference. Many more to print but a hundred is a milestone worth a picture, don't you think?

Thingiverse link: http://www.thingiverse.com/make:68301

Settings: MakerWare .3mm/low with linear fill with no support and no raft, on a Replicator 2. I've been printing six at a time, which takes about an hour. I'd do more but my build plate is warped - I know I should just order one but it is expensive! My reliability has been great, with just one lemon in the hundred I've printed so far. On one of the print runs I ran out of green filament halfway through and switched to black, as you can see in the picture.

Day 189 - Sierpinski tetrahedron

Today an amazing thing happened. It became possible to print a Sierpinski tetrahedron without internal supports on a desktop filament-based 3D printer. Not a fancy laser sintering powder printer that costs tens of thousands of dollars and uses expensive printing material to boot, but a simple Etch-a-Sketch-plus-glue-gun printer that can make an object as big as your hand for less than a cup of coffee. Two key things made this possible; two things that just WORK, no muss, no fuss. Sparks of genius.

The first key thing is an idea and model, both by owens on Thingiverse. He constructed a Customizable Sierpinski Tetrix model that can be printed with no supports other than a custom stand that prints underneath the model and is snapped off later. The spark of genius here is that owens' stand enables you to print the Sierpinski tetrahedron upside-down, and therefore in a configuration with no overhangs! Owens had done the same thing earlier for the Menger cube, which made us so happy that we printed and posted Menger cube models using owens' stand method for six days last month (Day 157, Day 161, Day 162, Day 169, Day 170, Day 171). I'll say what I said about this on the first day: sure, it's obvious now, but nobody else put the pieces together before owens did, and in addition his execution is great. The model easily breaks off the supporting stand it prints with; no muss, no fuss.

The second key thing is a machine: the MakerBot Replicator 2. I now have access to three of these machines, one in the JMU MakerLab in the Department of Mathematics and Statistics, one in the JMU 3-SPACE general education 3D-printing classroom, and one in my house, right here on my desk. This machine just works. Out of the box. With minimal fiddling with print settings and calibration. And it produces absolutely stunning prints, even at the .3mm/low resolution that we used today for the Sierpinski triangle. In my job running MakerLab and 3-SPACE I help maintain sixteen 3D printers of various makes and models. Some are ABS, some are PLA; some are multiple-extrusion and some are not; some work better than others and some need more attention than others. Each one fills a role in our lab and in our classroom, and each one breaks, has printing catastrophes, and has to be taken apart and put back together from time to time. We had some bumpy times early on as I was learning and the Replicator needed some replacement parts, but now that we've settled in, the Replicator 2 is the boss at printing mathematical objects. Your filament 3D printer doesn't have to be a Replicator 2 to print owens' Sierpinski triangle, but it sure as heck doesn't hurt.

So here it is! Today's amazing thing:

Thingiverse link: http://www.thingiverse.com/make:68254

Settings: MakerWare .3mm/low on a Replicator 2 with no raft and no supports. Prints with a stand that easily snaps off after printing.

Day 188 - Hinged Triangle-Square

Today we printed the famous hinged dissection called the Haberdasher's Puzzle from Henry Dudeney, who found a way to cut an equilateral triangle into four pieces that reassemble into a square. Dudeney's solution had an additional property, which is that the pieces could be hinged so as to swing from one form to the other. It's a beautiful construction and I was recently reminded of it by a tweet from WWMGT ("What Would Martin Gardner Tweet?"). Here are seven copies of the model, laid out so you can see the triangle turn into a square, and vice-versa:

C is at home for a(nother!) snow day with his friend E, who was kind enough to demonstrate how the Triangle-Square works in this short video.

Thingiverse link: http://www.thingiverse.com/thing:263152

Settings: MakerWare .3mm/low on a Replicator 2 with linear infill (just because it looks nicer when using translucent filament), in about 10 minutes, with no raft and no support.  The model prints in *one piece*, hinges and all.

Technical notes: This is the model we were working on in Friday's post about failing. It was created in OpenSCAD by modifying the code for our Fidget cube from Day 146. When I first started this project, I thought it would be a simple modification. Then I realized I didn't have coordinates for the dissection of the triangle. After some searching I found an explicit construction with coordinates in coordinates the MapleSoft article Animation of Dudeney's Dissection Transforming an Equilateral Triangle to a Square by Mark Meyerson of the U.S. Naval Academy. After some trial and error I got this worked into the following coordinates for points A, B, C, E, F, P, Q, R, and S in OpenSCAD code (where s is a scaling factor with default value 35mm):

A1=s*0; A2=s*0;

B1=s*1/2; B2=s*sqrt(3)/2;

C1=s*1; C2=s*0;

E1=(A1+B1)/2; E2=(A2+B2)/2;

F1=(B1+C1)/2; F2=(B2+C2)/2;

P1=(B1+s*sqrt(2*B2/s-(B2/s)*(B2/s)))/2; P2=0;

Q1=P1-s*1/2; Q2=P2-0;

R1=P1+(((F1-P1)*(E1-P1)+(F2-P2)*(E2-P2))/((E1-P1)*(E1-P1)+(E2-P2)*(E2-P2)))*(E1-P1);

R2=P2+(((F1-P1)*(E1-P1)+(F2-P2)*(E2-P2))/((E1-P1)*(E1-P1)+(E2-P2)*(E2-P2)))*(E2-P2);

S1=E1-R1+P1; S2=E2-R2+P2;

The second major problem was that the hinges needed to be angled and oriented to fit on non-square pieces, and also that some of the hinges needed to attach to angles that were much less than 90 degrees. These acute-angle hinges were unstable and didn't snap apart correctly after printing, so I had to add some stabilizing connectors and then some holes in opposite pieces to accommodate those connectors so the pieces could still fold flush to each other. What I hoped would be easily generalizable code that would work for any hinged dissection with given vertices and hinge locations quickly turned into a mess of one-use angles and hacks to make things close up correctly. But in the end we worked it all out, if messily. Perhaps in the future we'll make a more generalized OpenSCAD code for these constructions, but for today we are content just to be able to turn a triangle into a square and back again. And again, and again, and again.

UPDATE: This model got a shout-out in the post Using Manipulatives for a fun twist on Dan Meyer's geometry problem on the mikesmathpage blog. Nice ideas for how to use the Haberdasher triangle-square to get kids thinking openly about mathematics!

Day 187 - Spirograph

Thank you so much, Hercemer, for making a 41 Piece Spirograph collection available on Thingiverse!

Thingiverse link: http://www.thingiverse.com/make:68162

Settings: MakerWare .3mm/low on a Replicator 2, but my build platform is still a bit warped so I had trouble printing any rings larger than the blue one pictured here. I think it may be time to consider buying a new platform.

Stuff to change: I couldn't get the rectangular and triangular gears to work very well, but that may be because I needed a different size of large ring, or because I used "low" instead of "standard" layer height. More experimenting later!

Day 186 - Friday Fail

One thing I love about 3D printing is that it teaches you how to deal with failure. Lots and lots of failure. Every design I make ends with a pretty picture but starts with a stack of failed prints, and each one of those failed prints tells me how to redesign my model to be a little bit better. Printing a model to see how it is working is cheap, fast, and easy when you have a 3D printer, so you can literally "design to fail", that is, make a design that you know isn't quite right but then print it, learn from it, and fix your model or print settings accordingly. Failure is actually an active part of my design process.

The process of try/fail/try again is something that many of my math students have difficulty with; they can remember and repeat tasks but they often have trouble being creative and solving problems. For the calculus geeks out there, consider the difference between differentiation and anti-differentiation. Differentiation is simple for most functions and it would not be hard to write a computer program to do it; the process doesn't require much creativity. Anti-differentiation is another story; for example, the functions 1/(3x^2+2), x/(3x^2+2), and (3x^2+2)/x are fairly similar, but their antiderivatives are wildly different (one involves arctan, one involves logarithms, and one is a polynomial). Finding these anti-derivatives requires a willingness to make a guess, test out the guess, and then re-guess accordingly, and students have a lot of trouble doing that when they first encounter anti-derivatives. A lot of them don't like to try things that they aren't sure will work, and in addition are reluctant to try again when they fail the first time.

I hope that the use of 3D printing and modeling in K-12 schools will help my future students learn to fail. And how to pick themselves up, dust themselves off, and fail all over again. And again, and again!

So in celebration of failure, I'll stop hiding my catastrophes and put them up here for all to see. This week's Friday Fail is a collection of hinge tests for a project we will be posting later this week. The design is based off our old Print-in-Place Fidget Cube model, written in OpenSCAD. Some of the modules in the new design have angles of much less than 90 degrees that need to have hinges, and this causes a problem with stability and reliability. So we've been testing, retesting, coding, and recoding until we get it working just the way we want. Here are some of the failures that helped us on our way today:

Day 185 - Wishbone

Easy mashup time: Today we printed SimplusDesign's Wishbone Cookie Cutter Set on Thingiverse and Eckerput's Rolling Pin Spacer on Thingiverse so we can make some cookies! Also, a bonus: The rolling pin spacer can be resized into a really simple bracelet to use as a reward for winning the wishbone-breaking competitions that will ensue.

Thingiverse link for wishbone cutter: http://www.thingiverse.com/make:68121
Thingiverse link for rolling pin spacer: http://www.thingiverse.com/make:68122

Settings: MakerWare .3mm/low on a Replicator 2, with no raft and no support.

Technical notes: Eckerput made his rolling pin spacer in OpenSCAD, which makes it easily customizable to different rolling pin sizes and dough thicknesses. It's a great example of simple OpenSCAD code; if you're a beginner you could start with this example and then work on extending and modifying it into other projects:

// Rolling Pin Spacers
// all measurements are in mm

// by Eckerput
// http://www.thingiverse.com/thing:38943

// Diameter of rolling pin in mm (best if slightly smaller than actual)
pin = 46;
pinr=pin/2;

// How thick you want the dough to be in mm
Dough = 5;

difference () {
   cylinder (h=7,r=pinr+Dough, $fn = 200);
   translate ([0,0,-2]) cylinder (h=14,r=pinr, $fn = 200);
   translate ([0,0,-2]) cube([pinr+Dough+2,2,14]);
}

The code is probably fairly self-explanatory except for the "difference" command. This command works by creating the first object that is listed and then subtracting all objects listed after that. In this case, Eckerput is making a solid cylinder that it is 7 mm high and whose radius is enough to get around the rolling pin and make room for the desired thickness of dough.  The "$fn" part tells OpenSCAD to use 200 fragments to make the round part of the cylinder; this controls how smooth the cylinder will be. Using a value as high as $fn=200 can slow your code down significantly in more complicated examples, so when working with rough code I suggest using $fn=12 or not including any $fn directives. There are two things that have to be removed from the cylinder that was created on the first line of the difference command: first, the center of the cylinder, to allow room inside for your rolling pin; second, a small slit in the resulting annulus to give the ring some flexibility to enclose and grip the rolling pin. Note that in each of these objects to be removed, Eckerput made the height 14 instead of 7; this is so that those objects extend well past the original cylinder and do not share any faces with the original cylinder. Failing to do this can cause strange errors in OpenSCAD. For more information on how to get started with OpenSCAD, see the OpenSCAD User Manual.

Day 184 - Mystery pyramids

Today we made a lot of little pyramids and a box. Why? Can't tell you that right now, it's for a friend and we'll follow up later on this year with a reason.

Settings: As usual, MakerWare .3mm/low on a Replicator 2. We printed the pyramids three at a time at 80% and the box at 81% to add a little clearance that was missing in our first trial run. You could probably print more pyramids at a time but our build plate is a little warpy so we are currently trying to keep our prints small and near the center of the plate.

Technical notes: The OpenSCAD code is really simple; the only part to think about is how to find the height of a square-based pyramid with sides all of equal length. Get out your trigonometry hat: Given that the sides of the square are 30mm (based on our coordinates for those vertices in the code below), the Pythagorean theorem tells us that the diagonal of the base is 30*sqrt(2). Then the height of the pyramid is one leg of a right triangle whose other leg is length 30*sqrt(2)/2 (halfway across the diagonal) and whose hypotenuse is 30 (one of the slanted sides of the pyramid), so another application of the Pythagorean theorem gives us a height of 30/sqrt(2). Or you could just memorize that the height of an equilateral square pyramid is the side length divided by sqrt(2).

// mathgrrl packing problem

////////////////////////////////////////////////////////////////////
// renders
////////////////////////////////////////////////////////////////////

the_box();

//square_pyramid();

////////////////////////////////////////////////////////////////////
// module for square pyramid 
// from OpenSCAD manual example
// http://en.wikibooks.org/wiki/OpenSCAD_User_Manual/Primitive_Solids
////////////////////////////////////////////////////////////////////

module square_pyramid(){
polyhedron(
 points= [[15,15,0], [15,-15,0], [-15,-15,0], [-15,15,0], 
          [0,0,30/sqrt(2)] // top point
],                                 
 triangles=[ [0,1,4],[1,2,4],[2,3,4],[3,0,4], // each triangle side
             [1,0,3],[2,1,3] ] // two triangles for square base
);
}

////////////////////////////////////////////////////////////////////
// module for the box
////////////////////////////////////////////////////////////////////

module the_box(){
translate([0,0,76])
difference(){
cube([92,92,92],center=true);
translate([0,0,6]) cube([90,90,100],center=true);
}
}

Day 183 - Hiroshima University

To celebrate today's visit to the JMU 3-SPACE classroom from a group of students from Hiroshima University, we them made a nameplate logo design in Tinkercad.

STL file: http://www.geekhaus.com/makerhome/day183_hiroshimauniversity.stl

Tinkercad link: https://tinkercad.com/things/ehiCNeXkArt-day-183-hiroshima-university-logo-nameplate

Thingiverse link: http://www.thingiverse.com/thing:259145

Settings: MakerWare .3mm/low on a Replicator 2 with no raft and no support, oriented so the nameplate was face-down.

Technical notes: To import the logo into Tinkercad we opened a .jpg of the design in Inkscape, converted to bitmap, and then saved in .svg format. 

You can see pictures from the Hiroshima University visit at the JMU 3-SPACE blog.

Cool fact: Today marks the halfway point on our journey to 3D print and post about something every day for a year!

Day 182 - Voronoi die

Today we printed a copy of sirmakesalot's clever Bone Die on Thingiverse using our loaner Afinia H-Series:

Thingiverse link: http://www.thingiverse.com/make:67307

Settings: Afinia .3mm/low on "fast" with "only base" supports.

Day 181 - Hexagonal Borromean rings that print without support

Printing Borromean rings in three pieces minimizes support because the first two pieces need no support at all. In this model we've used a hexagonal ring shape with sides beveled so as to allow printing in one assembled piece with no support or raft needed! The "chain" demo file by sal on Thingiverse that comes with the Replicator 2's SD card was the inspiration for this beveled hex design. Although not as pretty as the three-color prints, when you need a quick set of Borromean rings you can't beat a print-in-place support-less model. But in case you want to try a three-color model, I've included files for that as well.

STL file, horizontal ring: http://www.geekhaus.com/makerhome/day181_borr_hex_piece12.stl
STL file, vertical ring: http://www.geekhaus.com/makerhome/day181_borr_hex_piece3.stl
STL file, together: http://www.geekhaus.com/makerhome/day181_borr_hex_together.stl
Thingiverse link: http://www.thingiverse.com/make:67202

Settings: MakerWare .3mm/low on a Replicator 2 with no raft and no supports, all in one piece!

Technical notes: Like yesterday, use the ellipse function and tubify module from Day 179 and then comment in the part you want to use from the code below.

////////////////////////////////////////////////////////////
// Borromean hexagons - all together (no supports needed!)
////////////////////////////////////////////////////////////

// set faces
$fn=6;

difference(){
// make the three rings
union(){
rotate([0,0,0]) rotate([45,45,0])
color("red") tubify(r=3.5,step=45,end=360);
rotate([0,0,120]) rotate([45,45,0])
color("yellow") tubify(r=3.5,step=45,end=360);
rotate([0,0,240]) rotate([45,45,0])
color("blue") tubify(r=3.5,step=45,end=360);
}
// hack to shave off base for good platform adhesion
translate([0,0,-45.4])
cube(50,center=true);
}

////////////////////////////////////////////////////////////
// Borromean hexagons - one at a time
////////////////////////////////////////////////////////////

/*
// set faces
$fn=6;

// hexagon ring
// print two of these
tubify(r=3.5,step=45,end=360);

// final hexagon ring
// print standing up and pause to assemble
// rotate([0,90,0]) tubify(r=3.5,step=45,end=360);
*/

Day 180 - Diamond Borromean

Same as Day 179 but with diamonds instead of ellipses! This version of the Borromean rings has more limited mobility but that restricted movement makes it naturally sit on your desk in a beautiful star shape:

STL file, horizontal diamond: http://www.geekhaus.com/makerhome/day180_borr_dia_piece12.stl
STL file, vertical diamond: http://www.geekhaus.com/makerhome/day180_borr_dia_piece3.stl
STL file, all together: http://www.geekhaus.com/makerhome/day180_borr_dia_together.stl
Thingiverse link: http://www.thingiverse.com/make:67201

Settings: MakerWare .3mm/low with no raft or support for the first two pieces, and both raft and support for the vertical piece. The vertical piece is oriented in such a way to need to support on its interior, while forcing support in a small area at its base for stability.

Technical notes: Using the ellipse function and tubify module from Day 179, uncomment the code below to get the type of model you want (single diamonds or all together).

////////////////////////////////////////////////////////////
// Borromean diamonds - all together
////////////////////////////////////////////////////////////

/*
// set faces
$fn=4;

// make the three rings
rotate([0,0,0]) rotate([56.6,56.6,0])
color("red") tubify(r=3,step=90,end=360);
rotate([0,0,120]) rotate([56.6,56.6,0])
color("yellow") tubify(r=3,step=90,end=360);
rotate([0,0,240]) rotate([56.6,56.6,0])
color("blue") tubify(r=3,step=90,end=360);
*/

////////////////////////////////////////////////////////////
// Borromean diamonds - do one at a time and then assemble
////////////////////////////////////////////////////////////

// set faces
$fn=4;

// diamond ring
// print two of these
scale(1.3) tubify(r=3.5,step=90,end=360);

// diamond ring
// print two of these
// scale(1.3) rotate([35,0,0]) rotate([0,90,0]) tubify(r=3.5,step=90,end=360);

Day 179 - Tricolor Borromean rings

Yesterday we mentioned that you could print a three-color model of the Borromean rings by printing the rings separately and placing the first and second in and around the third right before it closed up. We did that today, using more elliptical rings to make the assembly easier:

STL file, horizontal ring: http://www.makerhome.blogspot.com/day179_borr_ellipse_piece12.stl
STL file, vertical ring: http://www.makerhome.blogspot.com/day179_borr_ellipse_piece3.stl
Thingiverse link: http://www.thingiverse.com/make:67200

Settings: MakerWare .3mm/low on a Replicator 2 with the first two rings laying flat with no support or raft, and the third ring printing vertically with both raft and support. We used the custom slicing profile from Day 110, which made a very thin one-layer sheet up the center of the interior of the vertical ring. When we added the first two rings near the end of the print, this support sheet had to come out, which led to a few stray threads in subsequent rows that had to be removed. Files for the horizontal and vertical files are separately here because in later models, the orientation of the third piece will be important.

Technical notes, OpenSCAD flavor: The code is very simple; much like it was for Day 178, but with a less circular function for the rings. Remove the comments for the piece you want to print.

// mathgrrl Borromean 
// thanks to kitwallace for tubify module!

// an ellipse
function f(t) = 
[ 25*cos(t),
 15*sin(t),
 0
];

module tubify(r,step,end) {
for (t=[0: step: end+step]) {
hull() {
translate(f(t)) sphere(r);
translate(f(t+step)) sphere(r);
       }
   }
};


////////////////////////////////////////////////////////////
// Borromean ellipses - all together
////////////////////////////////////////////////////////////

/*
// set faces
$fn=36;

// make the three rings
rotate([0,0,0]) rotate([45,45,0])
color("red") tubify(r=3.5,step=10,end=360);
rotate([0,0,120]) rotate([45,45,0])
color("yellow") tubify(r=3.5,step=10,end=360);
rotate([0,0,240]) rotate([45,45,0])
color("blue") tubify(r=3.5,step=10,end=360);
*/

////////////////////////////////////////////////////////////
// Borromean ellipses - one at a time
////////////////////////////////////////////////////////////

// set faces
$fn=36;

// ellipse ring
// print two of these
tubify(r=3.5,step=10,end=360);

// final ellipse ring
// print one standing up and pause to assemble
//rotate([0,90,0]) tubify(r=3.5,step=10,end=360);

Day 178 - Borromean rings

When I give talks about 3D printing and knot theory, I often tell the story of my student Olivia who created and printed a 3D model of the Borromean rings as her first project in my class.  The Borromean rings consist of three rings arranged in such a way that no two of the rings are linked to each other, but the three together are linked and cannot come apart. Olivia's model came out beautifully, but she had a confession: no matter how hard she tried, she could not make the Borromean rings model out of circles. She reported to the class that she had to resort to using slightly elliptical rings instead of circles, and that in fact, she wasn't even sure that it was possible to construct the darn thing out circles. She had independently discovered what Linstrom and Zetterstrom proved in 1991 in their paper Borromean circles are impossible (American Mathematical Monthly, Vol. 98, Issue 4)! What's more, when you hold the 3D model in your hand it is immediately obvious why constructing the Borromean rings out of circles doesn't work.

Although I've told this story many, many times, it always ends on a lame note - with me realizing that I don't own a copy of Olivia's model to show! Today, I fixed that problem and made a model of the Borromean rings in OpenSCAD:

The rings don't touch each other and you can flatten them to get a braid link conformation of the form AbAbAb, or in other words, the spiral link S(3,3,(1,-1)).

STL file: http://www.geekhaus.com/makerhome/day178_borr_regular_together.stl
Thingiverse link: http://www.thingiverse.com/make:67199

Settings: MakerWare with our custom knot-slicing profile from Day 110 to minimize support. Only very thin sheets of support were generated, which worked wonderfully.

Technical notes: Using the parametric equations for an ellipse and kitwallace's tubify code, we get the following OpenSCAD code:

// mathgrrl Borromean

// nearly a circle
function f(t) = 
[ 25*cos(t),
 20*sin(t),
 0
];

module tubify(r,step,end) {
for (t=[0: step: end+step]) {
hull() {
translate(f(t)) sphere(r);
translate(f(t+step)) sphere(r);
       }
   }
};

// set faces
$fn=36;

// make the three rings
rotate([0,0,0]) rotate([45,45,0])
color("red") tubify(r=2.2,step=5,end=360);
rotate([0,0,120]) rotate([45,45,0])
color("yellow") tubify(r=2.2,step=5,end=360);
rotate([0,0,240]) rotate([45,45,0])
color("blue") tubify(r=2.2,step=5,end=360);

Stuff to change: If you printed these rings one at a time then you could slip the first two around/inside the third just before it finished printing. In that way you could make a cool three-color model! Here are the necessary files for a horizontal ring and a vertical ring.

Pictures of Olivia's original Borromean rings, which she constructed in Tinkercad, can be found at an old post of this story at jmumakerlab.blogspot.com.

Day 177 - Valentine tags

C's classroom Valentine's celebration was cancelled last week due to snow, and rescheduled for today. Stranded at home for a couple of days with no car and no Valentine's candy to bring to school, we decided to make nametags for the students in his class. A lot of C's classmates have very unique names so possibly they've never been able to get a nametag pencil, ruler, or trinket from one of those tourist trap displays. Hope they like these!

Tinkercad link: https://tinkercad.com/things/jSe1d1gCy7u-day-177-valentine-tags/edit

Settings: MakerWare .3mm/low, as usual. The stencil letters held together very well despite the small attaching lines.

Technical notes: These were very easy to make using Tinkercad's "MajorSnafu Text" shape script and Oliver's Tinkrecad "Chamfered and Rounded" community shape script. Follow the Tinkercad link and customize your own!

Day 176 - Geologhedra samples

Today we printed a small handful of polyhedra that represent crystal mineral models for geologist Amy Thompson at Bridgewater College. We used nischi's Crystal Structures Models on Thingiverse to start; in the future we hope to make OpenSCAD versions of a much large collection of crystal models, for example those cataloged by Cochise College or found in the Manual of Mineralogy and Petrology.

Thingiverse link: http://www.thingiverse.com/make:66462

Settings: MakerWare .3mm/low on a Replicator 2.

Day 175 - Metro wallet

I don't have a NYC Metro Card, but I hope to in the future. When I do, dadhoc's Slim Wallet with Metro Card Sliding Compartment on Thingiverse is where I want to keep it!

Thingiverse link: http://www.thingiverse.com/make:66460

Settings: Printed perfectly on a Replicator 2 with MakerWare on .3mm/low, no raft and no supports. The middle divider is just one path thick, and the overhang clip printed with no problems. Excellent design, dadhoc!

Stuff to change: Later I'd like to modify this design to make a Metro Card and small cash compartment that I can clip to the inside of my messenger bag.

Day 174 - MAA icosahedron

In a couple of days I'll be speaking at the Carriage House, the headquarters of the Mathematical Association of America. Since the MAA's logo is an icosahedron, I'll be bringing them one as a present:

STL file: http://www.geekhaus.com/makerhome/day174_MAAisosahedron.stl
OpenSCAD file: http://www.geekhaus.com/makerhome/day174_MAAisosahedron.scad
Thingiverse link: http://www.thingiverse.com/thing:252515

Settings: MakerWare .3mm/low with 5% infill (half as much as usual), on a Replicator 2, in about an hour. The black was added after printing with a Sharpie.

Technical notes: We printed hollow icosahedra on Day 32 and Day 100, but used a Community Shape Script file from Tinkercad that needed rotating to print on a flat face. Since I don't know how to rotate by non-integer degrees in Tinkercad, the rotation was not exact and some flat triangles had to be added to the top and base in order for the model to print correctly.  Today we finally got off our Keister and made a new icosahedron, constructing the triangle faces explicitly using the polyhedron command in OpenSCAD.  We used Harlan Martin's write.scad code from Thingiverse to add the text.

// mathgrrl MAA icosahedron

use <write.scad>

////////////////////////////////////////////////////////////////////
// parameters
////////////////////////////////////////////////////////////////////

$fn=12;
phi = (sqrt(5)-1)/2; 
scalefactor = 50; // 15 for small

////////////////////////////////////////////////////////////////////
// renders
////////////////////////////////////////////////////////////////////

// MAA logo sized for scalefactor 50
translate([1,-5,35])
color("red")
write("MAA",t=30,h=32,center=true);

icosahedron(scalefactor);

// uncomment this to see the vertices
//showvertices(scalefactor);

////////////////////////////////////////////////////////////////////
// module for icosahedron 
// vertex coords from Wikipedia
// http://en.wikipedia.org/wiki/Icosahedron#Cartesian_coordinates
////////////////////////////////////////////////////////////////////

module icosahedron(thescale){
scale(thescale)
// rotate to have flat top and base
rotate(-atan(1-phi),[1,0,0])
polyhedron(
// list the vertices in some order
points=[
[0,1,phi], //vx 0
[0,1,-phi], //vx 1
[0,-1,phi], //vx 2
[0,-1,-phi], //vx 3
[1,phi,0], //vx 4
[1,-phi,0], //vx 5
[-1,phi,0], //vx 6
[-1,-phi,0], //vx 7
[phi,0,1], //vx 8
[-phi,0,1], //vx 9
[phi,0,-1], //vx 10
[-phi,0,-1], //vx 11
],  
// define faces, each oriented counter-clockwise
triangles=[
// top face
[8,9,2],
// faces with edges incident with top face
[8,2,5],
[2,9,7],
[9,8,0],
// faces next row down
[8,4,0],
[8,5,4],
[2,3,5],
[2,7,3],
[9,6,7],
[9,0,6],
// faces another row down
[0,1,6],
[0,4,1],
[5,10,4],
[5,3,10],
[7,11,3],
[7,6,11],
// and one more down, with edges incident to bottom face
[4,10,1],
[3,11,10],
[6,1,11],
// bottom face
[10,11,1]
]
); 
}  

OpenSCAD's polyhedron command takes a list of vertices as inputs, followed by a list of triples of those vertices that determine oriented triangle faces. We got the coordinates for the vertices from Wikipedia's icosahedron page, and wrote a vertex visualizer to keep track of the twelve vertices and determine how to construct and orient the triangles. In case you want to use the same trick, here is the code for that vertex visualizer:

////////////////////////////////////////////////////////////////////
// vertex visualizer module 
// use for constructing oriented faces
////////////////////////////////////////////////////////////////////
module showvertices(thescale){
scale(thescale)
// rotate to have flat top and base
rotate(-atan(1-phi),[1,0,0])
union(){
// vertices in yz-plane
color("red") translate([0,1,phi]) sphere(.1); //vx 0
color("red") translate([0,1,-phi]) sphere(.2); //vx 1
color("red") translate([0,-1,phi]) cube(.1); //vx 2
color("red") translate([0,-1,-phi]) cube(.2); //vx 3
// vertices in xy-plane
color("blue") translate([1,phi,0]) sphere(.1); //vx 4
color("blue") translate([1,-phi,0]) sphere(.2); //vx 5
color("blue") translate([-1,phi,0]) cube(.1); //vx 6
color("blue") translate([-1,-phi,0]) cube(.2); //vx 7
// vertices in xz-plane
color("yellow") translate([phi,0,1]) sphere(.1); //vx 8
color("yellow") translate([-phi,0,1]) sphere(.2); //vx 9
color("yellow") translate([phi,0,-1]) cube(.1); //vx 10
color("yellow") translate([-phi,0,-1]) cube(.2); //vx 11
}
}

Day 173 - LEGO ring

Thank you, tart2000, for making this lovely LEGO Ring on Thingiverse. My son had a great time adding the bling!

Thingiverse link: http://www.thingiverse.com/make:65858

Settings: MakerWare .3mm/low on a Replicator 2, with no raft or supports.

Technical notes: We made this from tart2000's "less chunky" demo file without any changes or customizations. At first we thought the 2x2 LEGO plate was not going to fit in the ring, but a set of pliers told us differently. The tight design makes the ring really secure, and it is easy to add and remove things from the ring without the plate falling out. A simple, elegant design that just works!

Day 172 - Mobius Heart

Happy Valentine's Day!  In celebration, today we made a Möbius strip in the shape of a heart. The OpenSCAD code was kindly provided by kitwallace.

From the side you can more clearly see its Möbius-ness:

Thingiverse link: http://www.thingiverse.com/thing:249696
OpenSCAD code: http://www.geekhaus.com/makerhome/day172_kitwallace_mobiusheart.scad

Settings: MakerWare .3mm/low with no raft and no supports in 26 minutes.

Technical notes: Below is kitwallace's OpenSCAD code, in case you want to change any of the parameters for your own print.  The heart equations are the same ones we used in Day 133, with a sine curve thrown in on the z-coordinate for curviness.

// Mobius heart by kitwallace

//Radius of strip

Radius = 20;

//Width of Strip

Width = 7;

//Thickness of strip

Thickness=1.2;

//Half twists 0 is a collar, 1 is the mobius strip, 2 = full twist

Halftwist=1;

//Start Angle - important if Halftwist = 0

Start=90;

//Step size in degrees

Step = 2;

function f(t) =

[ 16*pow(sin(t),3),

  13*cos(t)-5*cos(2*t)-2*cos(3*t)-cos(4*t),

  5*sin(2*t)

];

module mobius_strip(radius,width,thickness,step=3,halftwist=3,start=90) {

  for (i = [0:step:360])

   hull() {

    translate(f(i))

     rotate([0,start+i * halftwist * 0.5, 0])

       cube([width,Delta,thickness], center=true);

    translate(f(i+step))

     rotate([0,start+(i+step)* halftwist * 0.5 , 0])

       cube([width,Delta,thickness], center=true);

  }

}

Delta= 0.1;

mobius_strip(Radius,Width,Thickness,Step,Halftwist,Start);